Vous developpez votre propre site web et vous souhaitez le tester sous Internet Explorer 7 ? Mais vous n’êtes pas vous, vous ne voulez pas l’installer sur votre ordinateur…
Et bien, j’ai l’astuce pour vous !!!
Avec ce tuto, vous pourrez executer Internet Explorer 7 Beta sans avoir besoin de l’installer.
1. Tout d’abord, téléchargez Internet Explorer 7 Beta 2
2. Ensuite, utilisez Winrar pour decompresser le programme d’installation dans un repertoire (ex: C:\Program Files\Internet Explorer 7) ou si vous ne voulez pas utilisez Winrar, mettez vous en ligne de commande, puis placez vous là ou se trouve le programme d’installation et tapez la commande suivante:
« IE7BETA2-WindowsXP-x86-enu.exe -e » (sans les guillemets)
3. Puis créez un fichier ie7.bat contenant le script suivant: (Merci à Jon Galloway)
@ECHO OFF
TITLE IE7 Launcher 1.4
ECHO IE7 STANDALONE LAUNCHER 1.4
ECHO Updated for IE7 Beta 2 Preview
ECHO.
ECHO Do not close this window or it will not clean up after itself properly.
ECHO You can pass a URL into this batch file, like this:
ECHO ie7.bat www.microsoft.com
ECHO.
ECHO More info here: http://weblogs.asp.net/jgalloway/archive/2005/12/28/434132.aspx
ECHO.
ECHO When you close IE7, this will remove the registry key and shut itself down.
ECHO.
ECHO Setting up IE7 for standalone mode...
PUSHD %~dp0
ECHO Removing IE7 registry key and set the version vector to "7.0000".
> %TEMP%.\IE7Fix.reg ECHO REGEDIT4
>>%TEMP%.\IE7Fix.reg ECHO.
>>%TEMP%.\IE7Fix.reg ECHO [-HKEY_CLASSES_ROOT\CLSID\{C90250F3-4D7D-4991-9B69-A5C5BC1C2AE6}]
>>%TEMP%.\IE7Fix.reg ECHO [-HKEY_CLASSES_ROOT\Interface\{000214E5-0000-0000-C000-000000000046}]
>>%TEMP%.\IE7Fix.reg ECHO [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer\Version Vector]
>>%TEMP%.\IE7Fix.reg ECHO "IE"="7.0000"
>>%TEMP%.\IE7Fix.reg ECHO.
:: Merge the REG file to delete the IE7 standalone entry
REGEDIT /S %TEMP%.\IE7Fix.reg
REN SHLWAPI.DLL SHLWAPI.DLL.BAK
TYPE NUL > IEXPLORE.exe.local
ECHO Running IE7...
iexplore.exe "%1"
:: Merge the REG file to delete the IE7 standalone entry
REGEDIT /S %TEMP%.\IE7Fix.reg
:: Delete the temporary REG file
DEL %TEMP%.\IE7Fix.reg
ECHO Removing IE7 standalone files...
REN SHLWAPI.DLL.BAK SHLWAPI.DLL
DEL IEXPLORE.exe.local
:: Set the old version vector "6.0000".
> %TEMP%.\IE7Fix.reg ECHO REGEDIT4
>>%TEMP%.\IE7Fix.reg ECHO.
>>%TEMP%.\IE7Fix.reg ECHO [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer\Version Vector]
>>%TEMP%.\IE7Fix.reg ECHO "IE"="6.0000"
>>%TEMP%.\IE7Fix.reg ECHO.
REGEDIT /S %TEMP%.\IE7Fix.reg
DEL %TEMP%.\IE7Fix.reg
POPD
ECHO Complete, closing...
4. Créez ensuite un fichier ie7.vbs et copiez collez y le script suivant:
Set oShell = CreateObject("WScript.Shell")
oShell.Run "ie7.bat", 0, True
5. Faites vous ensuite un petit raccourci sur le bureau pointant vers ce fichier ie7.vbs
Et voilà, maintenant vous avez un Internet Explorer 7 qui fonctionne en solo tout en cohabitant avec IE 6.
Il y a juste 2 petits bugs. Le premier est que lorsque vous taperez une URL dans IE6 une nouvelle fenetre s’ouvrira vers ce site. Et le second est que dans IE 7, la fonction des onglets sera indisponible.
Mais bon, ce n’est pas très handicapant pour faire vos tests d’affichage. Et n’oublier pas d’installer FireFox !
si ce n’est pas déjà fait !
